Publicité

Function File_Exist(PathName)
   Dim fso
   Set fso = CreateObject("Scripting.FileSystemObject")
   If (fso.FileExists(PathName)) Then
      File_Exist = true
   Else
      File_Exist = false
   End If
   Set fso = Nothing
End Function

La fonction "File_Write" permet d'écrire une chaine de caractères dans un fichier.
Si le fichier n'existe pas, cette fonction le crée automatiquement.
PathName = nom du fichier avec son chemin physique.
contenu   = chaîne de caractères à écrire.
mode = mode d'écriture, si mode=2 erit en écrasant l'ancien contenu, si mode=8 ecrit à la suite du contenu déjà présent dans le fichier.
La fonction retourne :
   0 => l'écritue a été réalisée,
   1 => l'écriture n'a pas été faite car le fichier est en lecture seule.

Function File_Write(PathName, contenu, mode)
   Dim fso,MyFile,ts
   Set fso = CreateObject("Scripting.FileSystemObject")
   If (fso.FileExists(PathName)) Then
      Set MyFile = fso.GetFile(PathName)
      If (MyFile.attributes and (1 or 16 or 1024 or 2048)) Then
         File_Write = 1
      Else
         Set ts = MyFile.OpenAsTextStream(mode)
         ts.Write contenu
         ts.close
         File_Write = 0
      End If
      Set MyFile = Nothing
   Else
      Set MyFile = fso.OpenTextFile(PathName, mode, true)
      MyFile.Write contenu
      MyFile.Close
      File_Write = 0
   End if
   Set fso = Nothing
End Function

La fonction "File_Read" retourne une chaîne de caractères représentant le contenu d'un fichier.
Si le fichier n'existe pas la fonction retourne une chaîne de caractères vide.
PathName = nom du fichier avec son chemin physique.

Function File_Read(PathName)
   Dim fso,MyFile,fichier
   fichier = ""
   Set fso = CreateObject("Scripting.FileSystemObject")
   If (fso.FileExists(PathName)) Then
      Set MyFile = fso.OpenTextFile(PathName, 1)
      fichier = MyFile.ReadAll
      MyFile.Close
   End If
   Set fso = nothing
   File_Read = fichier
End Function

La fonction "File_Copy" copie un fichier.
Si le fichier destination existe déjà, son contenu sera écrasé par le contenu du fichier à copier.
PathName_Source = nom du fichier à copier avec son chemin physique.
PathName_Destination = nom du fichier destination avec son chemin physique.
La fonction retourne :
   0 => la copie a été faite,
   1 => la copie n'a pas été faite car le fichier source n'existe pas,
   2 => la copie n'a pas été faite car le fichier destination est en lecture seule.

Function File_Copy(PathName_Source, PathName_Destination)
   Dim fso,Destination
   Set fso = CreateObject("Scripting.FileSystemObject")
   If (fso.FileExists(PathName_Source)) Then
      If (fso.FileExists(PathName_Destination)) Then
         Set Destination = fso.GetFile(PathName_Destination)
         If (Destination.attributes and (1 or 16 or 1024 or 2048)) Then
            File_Copy = 2
         Else
            fso.CopyFile PathName_Source, PathName_Destination
            File_Copy = 0
         End If
         Set Destination = Nothing
      Else
         fso.CopyFile PathName_Source, PathName_Destination
         File_Copy = 0
      End If
   Else
      File_Copy = 1
   End If
   Set fso = nothing   
End Function

La fonction "File_Delete" permet de supprimer un fichier.
PathName = nom du fichier avec son chemin physique.
La fonction retourne :
   0 => la suppression a été réalisée,
   1 => la copie n'a pas été faite car le fichier n'existe pas,
   2 => la suppression n'a pas été faite car le fichier est en lecture seule.

Function File_Delete(PathName)
   Dim fso
   Set fso = CreateObject("Scripting.FileSystemObject")
   If (fso.FileExists(PathName)) Then
      Set MyFile = fso.GetFile(PathName)
      If (MyFile.attributes and (1 or 16 or 1024 or 2048)) Then
         File_Delete = 2
      Else
         MyFile.Delete
         File_Delete = 0
      End If
      Set MyFile = Nothing
   Else
      File_Delete=1
   End If
   Set fso = nothing   
End Function